En attribuant un nom particulier à une macro, la macro pourra s'exécuter lors de
certains évènements comme l'ouverture d'un document, la création d'un nouveau document.

Nécessite d'activer la référence "Microsoft Word xx.x Object Library".

Dim WordApp As Word.Application
 
    Set WordApp = CreateObject("Word.Application")
    WordApp.Visible = True
 
    WordApp.Documents.Open ("C:\monDocument.dot")
    WordApp.Run "laMacro"

Un petit tutoriel pour vous guider : Les cinq syntaxes de base du langage VBA

Quelques exemples standards. Sélectionner tout le document

objDoc.Range(0, 0).Select
Selection.MoveEnd wdStory

Aller au début du document

Selection.HomeKey Unit:=wdStory

Aller à la fin du document

Selection.EndKey Unit:=wdStory

Sélectionner une ligne

Selection.EndKey Unit:=wdLine, Extend:=wdExtend

Sélectionner le troisième paragraphe

objDoc.Paragraphs(3).Range.Select

Sentences est une collection renvoyant les "phrases" de son conteneur (document, paragraphe ...). Par phrase on entend tout ce qui est compris entre des points et/ou des retours chariots.

'Notez que c'est donc différent des lignes word
Dim objDoc As Document, Phrase As Range
 
Set objDoc = Application.Documents.Open("D:\tuto.doc")
MsgBox objDoc.Sentences.Count & vbCrLf & objDoc.BuiltInDocumentProperties(wdPropertyLines)
For Each Phrase In objDoc.Sentences
    Phrase.Select
    MsgBox "suite"
Next

Alors que les versions précedentes de Word permettaient une recherche rapide du dernier point d'insertion dans le document, la version 2007 ne possède plus cette fonctionnalité. Le code fournit ci-dessous permet de palier ce manque.

Vous devez utiliser deux codes, l'un sur l'ouverture et l'autre sur la fermeture du document. Sur l'ouverture, pour atteindre un signet et le supprimer. Sur la fermeture, pour ajouter un signet à l'endroit de la dernière édition.

Sub Document_Open()
ActiveDocument.Bookmarks("ICI").Select
ActiveDocument.Bookmarks("ICI").Delete
End Sub

Sub Document_Close()
With Selection
    .Bookmarks.Add "ICI"
End With
 
End Sub

Vous pouvez placer ce code dans le document que vous éditez, auquel cas il ne fonctionnera que pour ce document, ou dans le Normal.dotm, et il sera utilisé pour tous vos documents.

Lors de l'appel en VBA d'une application autre que l'application hôte, il est impératif d'ajouter la bibliothèque de cette application à votre projet.

Ne pas ajouter cette référence, revient à utiliser des types de données qui sont inconnus.

On ajoute ces références par le menu "Outils" "Références" de l'éditeur VBE. La boîte de dialogue contient la liste des bibliothèques disponibles.

Il est possible d'utiliser une macro se trouvant dans un autre document. Il faut pour cela que le document contenant la procédure soit ouvert.

Documents("MonDocument.docm").MaRoutine

Avec "MaRoutine" le nom de la macro située dans l'autre document.

Les fondamentaux des Variables et des Constantes en VBA Débutez en VBA

L'objet Screen n'existant pas en VBA, on peut retrouver ces valeurs en utilisant les fonctions de l'API Win32 :

Private Declare Function GetDC Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function ReleaseDC Lib "user32" (ByVal hwnd As Long, ByVal hdc As Long) As Long
Private Declare Function GetDeviceCaps Lib "gdi32" (ByVal hdc As Long, ByVal nIndex As Long) As Long
 
Private Const HWND_DESKTOP As Long = 0
Private Const LOGPIXELSX As Long = 88
Private Const LOGPIXELSY As Long = 90
 
Function TwipsPerPixelX() As Single
Dim lngDC As Long
    lngDC = GetDC(HWND_DESKTOP)
    TwipsPerPixelX = 1440 & / GetDeviceCaps(lngDC, LOGPIXELSX)
    ReleaseDC HWND_DESKTOP, lngDC
End Function
 
Function TwipsPerPixelY() As Single
Dim lngDC As Long
    lngDC = GetDC(HWND_DESKTOP)
    TwipsPerPixelY = 1440 & / GetDeviceCaps(lngDC, LOGPIXELSY)
    ReleaseDC HWND_DESKTOP, lngDC
End Function

L'objet ClipBoard n'existant pas en VBA, il faut utiliser les fonctions de l'API Windows :

'-- Déclaration des fonctions API
Private Declare Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function CloseClipboard Lib "user32" () As Long
Private Declare Function EmptyClipboard Lib "user32" () As Long
 
Private Sub Commande0_Click()
    OpenClipboard 0 
    EmptyClipboard
    CloseClipboard
End Sub

On utilise la décomposition du range en Start et End

ActiveDocument.Range(ActiveDocument..Bookmarks("sig1").Range.Start, _
ActiveDocument..Bookmarks("sig2").Range.End).Select

Cela permet de gérer des opérations sur une plage sans modifier l'emplacement du point d'insertion. Supposons que je veuille insérer deux signets, l'un sur un mot, l'autre sur le point d'insertion, je peux faire :

Selection.TypeText Text:="Monsieur "
Set objRange = Selection.Words.First.Previous(wdWord)
objRange.Bookmarks.Add "genre"
With ActiveDocument.Bookmarks
    .Add Range:=Selection.Range, Name:="Nom"
    .DefaultSorting = wdSortByName
    .ShowHidden = True
End With

Pour changer l'imprimante par défaut en Word, c'est n'est pas sur la collection documents qu'il faut agir mais sur l'objet application.

Sub printPDF()
 
Dim oldprint
oldprint = Application.ActivePrinter
Application.ActivePrinter = "PDFCreator"
ActiveDocument.PrintOut
Application.ActivePrinter = oldprint
End Sub

Le code ci-dessus permet de changer l'imprimante par défaut en activant PDFCreator et après l'impression, change de nouveau l'imprimante par défaut en reprenant l'imprimante du départ.

Dans le déroulement d'un code, il est parfois intéressant de connaître le type de variable utilisée.

VarType(MaVariable)

Les résultats renvoyés sont sous la forme d'un entier.

Il existe deux grand principe pour la déclaration de vos objets en VBA :
- Le EarlyBinding
- Le LateBinding

EarlyBinding
On pourrait traduire par liaison précoce. Ce mode de déclaration signifie que l'on a ajouté la bibliothèque l'application dans les références du projet. L'avantage est la possibilité d'utiliser l'IntelliSense ou Auto-Completion lors de l'écriture de votre code.

L'avantage est que vous éliminez des erreur de frappe ou de syntaxe lors de l'écriture votre code.
L'inconvenient est que si vous distribuez votre projet, les bibliothèques doivent aussi se trouver sur les autres PC.

Sub ConnexionDBAccess()
'Déclaration des variables
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim sql As String
'Affectation de la sentence SQL
sql = "SELECT * From T_Adresses"
'Affectation des Objets d'access aux données
Set db = DBEngine.OpenDatabase( _
   "C:\Documents and Settings\Olivier\Mes documents\Mes sources de données\DB_Publipostage.mdb")
Set rs = db.OpenRecordset(sql)
'Boucle pour la récupération des données
While Not rs.EOF
Debug.Print rs.Fields(2)
rs.MoveNext
Wend
'Libération des objets
rs.Close
db.Close
 
Set rs = Nothing
Set db = Nothing
 
End Sub

LateBinding
On pourrais traduire pas liaison tardive. Dans l'explication précédente, la bibliothèque etéit ajoutée au projet dès le début. Dans ce mode, la bibliothèque est appelée dans le code.
L'avantage principal, c'est que votre code peut être distibué sans avoir à tenir compte de la version disponible de l'application.
L'inconvenient, ce mode ne permet pas l'utilisation de l'IntelliSense.

Sub OuvrirFichierXL()
Dim xlApp As Object
Dim xlWb As Object
 
Set xlApp = CreateObject("Excel.Apllication")
Set xlWb = xlApp.WoorkBooks.Add
 
xlApp.Visible = True
End Sub

Il y a beaucoup de confusion possible entre range et selection or les deux objets sont différents. Pour pouvoir basculer facilement de l'un à l'autre il faut utiliser une variable Range. Prenons un exemple

Dim objDoc As Document
 
Set objDoc = Application.Documents.Open("c:\jmarc\tuto.doc")
objDoc.Paragraphs(3).Range.Select
objDoc.Paragraphs(3).Range.EndOf wdWord, wdMove

Là, malgré le EndOf, le paragraphe est encore selectionné

Dim objDoc As Document, objRange As Range
 
Set objDoc = Application.Documents.Open("c:\jmarc\tuto.doc")
objDoc.Paragraphs(3).Range.Words(objDoc.Paragraphs(3).Range.Words.Count - 2).Select
Set objRange = objDoc.Paragraphs(3).Range
objRange.EndOf wdWord, wdMove
objRange.Select

Place le point d'insertion après le troisième paragraphe

Nécessite d'activer la référence "Microsoft Word xx.x Object Library" :

Dans l'exemple ci-dessous le signet à renseigner doit être nommé "SignetDate"

Dim WordApp As Word.Application
Dim WordDoc As Word.document
 
    Set WordApp = New Word.Application
    WordApp.Visible = True
    Set WordDoc = WordApp.Documents.Open("monDocument.doc")
 
    WordDoc.Bookmarks("SignetDate").Range.Text = Format(Now, "dd/mm/yyyy")

Lorsque le niveau de sécurité intrinsèque des documents Office est réglé sur moyen ou élevé, il est alors impossible d'activer automatiquement les macros d'un document.

La première solution consiste à régler le niveau de sécurité sur faible (Menu Outils Macros Sécurité...), mais n'est pas très recommandée.

L'autre solution consiste à auto-certifier les macros d'un document.
Un certificat local, valable uniquement sur la machine sur laquelle il est installé, va vous permettre d'éviter le désagrément d'avoir à confirmer l'activation des macros à l'ouverture d'un document, ou pire, la désactivation systématique des macros.

Comment procéder :

• Rechercher dans le répertoire d'installation de Microsoft Office (généralement C:\Program Files\Microsoft Office\OfficeXX) le programme SelCert.exe
• Exécuter SelfCert.exe
• Renseigner le nom du certificat dans la zone de texte et valider
• Fermer SelfCert.exe

• Ouvrir le document Office dont les macros doivent être certifiées
• Dans l'éditeur VBA (Alt-F11), menu Outils Signature électronique ...
• Cliquer sur "Choisir..." et sélectionner le certificat précédemment créé
• Enregistrer le document

A la prochaine ouverture du document, une alerte de sécurité va apparaître, cocher alors la case "Toujours faire confiance aux macros provenant de... ".

Pour supprimer un certificat existant :

• Panneau de configuration Options Internet
• Onglet Contenu, cliquer sur Certificats...
• Sélectionner le certificat et cliquer sur Supprimer

Deux méthodes pour changer le répertoire par défaut de Word.
La première est permanente

Application.Options.DefaultFilePath(wdDocumentsPath) = "c:\temp"

La seconde n'est valable que pour la session Word en cours, si vous fermez Word, ce paramètre disparaît.

Application.ChangeFileOpenDirectory "C:\temp"

En principe, une fonction ne peut renvoyer qu'une seule variable. Partant de là, il est possible d'utiliser une variable de type utilisateur.

Type MyVar
    IntA As Integer
    IntB As Integer
End Type

Voilà un type de donnée défini par l'utilisateur.

Sub MaProc()
Dim MyData As MyVar
 
With MyData
    .IntA = 10
    .IntB = 20
End With
MyData = monCalcul(MyData)
Debug.Print MyData.IntA, MyData.IntB
 
End Sub

Voilà un procédure qui va faire appel à une fonction et passer en paramètre une variable qui contient 2 valeurs.

Public Function monCalcul(MyDt As MyVar) As MyVar
monCalcul.IntA = MyDt.IntA * 2
monCalcul.IntB = MyDt.IntB / 4
 
End Function

Notre fonction renvoie bien deux résultats

Pour récupérer les fautes d'un document, il faut faire appel à la collection SpellingErrors. Nous allons parcourir les membres ce cette collection, les ajouter à une variable et ensuite, insérer la variable dans un nouveau document qui sera sauvegardé au format texte.

Sub Fautes()
Dim mesFotes
Dim toutesmesfotes
 
For Each mesFotes In ActiveDocument.SpellingErrors
mesFotes.Select
toutesmesfotes = toutesmesfotes & vbCrLf & Selection
Next mesFotes
Application.Documents.Add
ActiveDocument.Content.InsertAfter toutesmesfotes
ActiveDocument.SaveAs FileName:="c:\temp\mesftes.txt", FileFormat:=wdFormatText
ActiveDocument.Close
 
 
End Sub

C'est assez facile. L'exemple suivant affecte la mise en exposant à CTRL+MAJ+E

   CustomizationContext = NormalTemplate
    KeyBindings.Add KeyCode:=BuildKeyCode(wdKeyE, _
	  wdKeyControl, wdKeyShift), KeyCategory:=wdKeyCategoryCommand, Command:="Superscript"

Oui, il faut par contre demander le calcul pour une statistique

Dim objDoc As Word.Document, msg As String
 
Set objDoc = Application.Documents.Open("d:\tuto.doc")
MsgBox "Le documents contient " & objDoc.ComputeStatistics(wdStatisticPages) & _
" pages et " & objDoc.ComputeStatistics(wdStatisticWords) & " mots"

Vous pouvez obtenir les statistiques pour

• wdStatisticCharacters : nombre de caractères
• wdStatisticCharactersWithSpaces : nombre de caractères avec les espaces
• wdStatisticLines : nombre de lignes
• wdStatisticPages : nombre de pages
• wdStatisticParagraphs : nombre de paragraphes (retour chariot)
• wdStatisticWords : nombre de mots

Pour faire appel à une boîte de dialogue :

Dialogs(wdDialogFileOpen).Show

Je vous conseille de consulter l'aide pour obtenir la liste de toutes les boîtes de dialogue disponibles.

L'éditeur VBA (VBE) possède une fonction qui ouvre une liste déroulante lorsuqe l'on écrit du code.
Si cette fonction n'est pas disponible, c'est que la bibliothèque associée au code que vous utilisez n'a pas été ajoutée à votre projet.

Cette notation n'est pas obligatoire, mais elle rend la saisie et la compréhension du code plus facile.
Ainsi les deux lignes suivantes sont équivalentes :

Set oTbl = ActiveDocument.Tables.Add(Range:=Selection.Range, NumRows:=11, Numcolumns:=11)

Set oTbl = ActiveDocument.Tables.Add(Selection.Range, 11, 11)

Si certains arguments sont optionnels et ne sont pas renseignés, si vous n'utilisez pas la notation avec le nom et le :=, vous devrez utiliser des espaces entre les séparateurs. Il est beaucoup plus facile d'utiliser le nom des arguments, même si la saisie du code est un peu plus longue.

Set oDoc = Documents.Add(Visible:=yes)

Set oDoc = Documents.Add(, , , yes)

Le premier des deux code est plus explicite !